APDL中读取不连续节点编号并赋节点应力zz

http://www.mememama.cn/2010/0815/1058.html

!**************问题描述*************
!开空方板一边固定一边受拉的受力分析
!目标：研究APDL中读取不连续节点编号并赋节点应力
!好处：为下一步施加等效力提供便利
 

 
 

FINISH
/CLEAR
/prep7 
ET,1,42
MP,EX,1,2.06e5 
MP,PRXY,1,0.3  
RECTNG,-100,100,-100,100,  
CYL4, , ,50
ASBA,1,2
LESIZE,ALL, , ,10, , , , ,1
MSHAPE,1,2D
MSHKEY,0
AMESH,ALL  

/PREP7
LSEL,S, , , 8
NSLL,R,1
CM,N_TESTGRP,NODE       !创建节点集N_TESTGRP
NPLOT  
NLIST 
/PNUM,NODE,1
/REPLOT

*GET,N_COUNT,NODE,,COUNT    !创建变量N_COUNT并赋值当前节点集中的节点数
*DIM,N_ORDER,ARRAY,N_COUNT    !创建名为N_ORDER的一维数组
*GET,N_ORDER(1),NODE,,NUM,MIN  !将当前节点集中最小的节点号赋给N_ORDER(1)

*DO,I,1,N_COUNT-1
N_ORDER(I+1)=NDNEXT(N_ORDER(I)) !将比N_ORDER(I)大的下一个激活的节点号写入N_ORDER(I+1)
*ENDDO
*STATUS,N_ORDER

/SOLU
LSEL,S,LOC,X,-100
DL,ALL,,ALL
NSEL,S,LOC,X,100
F,ALL,FX,100
ALLSEL,ALL,ALL
SOLVE
/POST1
PLNSOL,S,EQV

*DIM,N_STRESS,ARRAY,N_COUNT,2      !创建名为N_STRESS的2维数组
*DO,I,1,N_COUNT
N_STRESS(I,1)=N_ORDER(I)         !将N_TESTGRP中的节点号赋给N_STRESS的第一列
*GET,N_STRESS(I,2),NODE,N_ORDER(I),S,X  !将上述节点的X方向上的应力赋给N_STRESS的第二列
*ENDDO
*VEDIT,N_STRESS             !列表察看N_STRESS的内容